• Articles
• admin

Sammendrag

Denne artikkelen viser hvordan Du bruker Automatisering til å opprette Og sende En Microsoft Outlook-melding I Microsoft Access 2000.
Microsoft gir programmerings eksempler for illustrasjon, uten garanti verken uttrykt eller underforstått. Dette inkluderer, men er ikke begrenset til, underforståtte garantier om salgbarhet eller egnethet for et bestemt formål. Denne artikkelen forutsetter at du er kjent med programmeringsspråket som blir demonstrert, og med verktøyene som brukes til å opprette og feilsøke prosedyrer. Microsofts kundestøtteteknikere kan bidra til å forklare funksjonaliteten til en bestemt prosedyre, men de vil ikke endre disse eksemplene for å gi ekstra funksjonalitet eller konstruere prosedyrer for å oppfylle dine spesifikke krav.
OBS! følgende kode fungerer kanskje ikke riktig hvis Du har installert Sikkerhetsoppdateringen For Outlook-E-post. Hvis du vil ha mer informasjon om denne oppdateringen, kan du se en av følgende artikler I Microsoft Knowledge Base, avhengig av hvilken Versjon Av Outlook du har:

262631 OL2000: Informasjon om Sikkerhetsoppdateringen For E-post I Outlook

262617 OL98: Informasjon Om Sikkerhetsoppdateringen For Outlook-E-post
Du Kan bruke SendObject-metoden til å sende en mapi-e-postmelding programmatisk I Microsoft Access. SendObject-metoden gir deg imidlertid ikke tilgang til fullstendig e-postfunksjonalitet, for eksempel muligheten til å legge ved en ekstern fil eller angi viktig melding. Eksemplet som følger, bruker Automatisering til å opprette og sende en e-postmelding som du kan bruke til å dra nytte Av Mange funksjoner I Microsoft Outlook som Ikke er tilgjengelige Med SendObject-metoden.
det er seks hovedtrinn for å sende En Microsoft Outlook-e-postmelding Ved Hjelp Av Automatisering, som følger:

1. Initialiser Outlook-økten.

2. Opprett en ny melding.

3. Legg til mottakerne (TIL, KOPI og BLINDKOPI) og løs opp navnene deres.

4. Angi gyldige egenskaper, For Eksempel Emne, Kropp og Betydning.

5. Legg til vedlegg (hvis noen).

6. Vis / Send meldingen.

Sende En Microsoft Outlook-E-Postmelding Programmatisk

1. Opprett en eksempeltekstfil med Navnet Kunder.txt i C:\My Dokumenter mappe.

2. Start Microsoft Access, og åpne eksempeldatabasen Northwind.mdb.

3. Opprett en modul og skriv inn følgende linje i Deklarasjoner-delen hvis den ikke allerede er der:

   Option Explicit
   

4. klikk Referanser På Verktøy-menyen.

5. klikk For å velge Microsoft Outlook 9.0-Objektbiblioteket i Referanser-boksen, og klikk DERETTER OK.
   OBS!: Hvis Microsoft Outlook 9.0-Objektbiblioteket ikke vises I Boksen Tilgjengelige Referanser, kan Du søke etter Filen Msoutl9 på harddisken.olb. Hvis du ikke finner denne filen, må Du kjøre Installasjonsprogrammet For Microsoft Outlook for å installere den før du fortsetter med dette eksemplet.

6. Skriv inn følgende fremgangsmåte i den nye modulen:

   Sub SendMessage(Optional AttachmentPath)
   Dim objOutlook As Outlook.Application
   Dim objOutlookMsg As Outlook.MailItem
   Dim objOutlookRecip As Outlook.Recipient
   Dim objOutlookAttach As Outlook.Attachment
   ' Create the Outlook session.
   Set objOutlook = CreateObject("Outlook.Application")
   ' Create the message.
   Set objOutlookMsg = objOutlook.CreateItem(olMailItem)
   With objOutlookMsg
   ' Add the To recipient(s) to the message.
   Set objOutlookRecip = .Recipients.Add("Nancy Davolio")
   objOutlookRecip.Type = olTo
   ' Add the CC recipient(s) to the message.
   Set objOutlookRecip = .Recipients.Add("Andrew Fuller")
   objOutlookRecip.Type = olCC
   ' Set the Subject, Body, and Importance of the message.
   .Subject = "This is an Automation test with Microsoft Outlook"
   .Body = "Last test - I promise." & vbCrLf & vbCrLf
   .Importance = olImportanceHigh 'High importance
   ' Add attachments to the message.
   If Not IsMissing(AttachmentPath) Then
   Set objOutlookAttach = .Attachments.Add(AttachmentPath)
   End If
   ' Resolve each Recipient's name.
   For Each objOutlookRecip In .Recipients
   objOutlookRecip.Resolve
   If Not objOutlookRecip.Resolve Then
   objOutlookMsg.Display
   End If
   Next
   .Send
   End With
   Set objOutlookMsg = Nothing
   Set objOutlook = Nothing
   End Sub
   

7. hvis du vil teste denne prosedyren, skriver du inn følgende linje I Umiddelbar-vinduet, og trykk DERETTER ENTER:

   SendMessage "C:\My Documents\Customers.txt"
   

   for å sende meldingen uten å angi et vedlegg, utelat argumentet når du ringer prosedyren, som følger:

   SendMessage