• Articles
• admin

Resumen

Este artículo muestra cómo usar la automatización para crear y enviar un mensaje de Microsoft Outlook en Microsoft Access 2000.
Microsoft proporciona ejemplos de programación solo para ilustración, sin garantía expresa o implícita. Esto incluye, pero no se limita a, las garantías implícitas de comerciabilidad o idoneidad para un propósito particular. Este artículo asume que está familiarizado con el lenguaje de programación que se está demostrando y con las herramientas que se utilizan para crear y depurar procedimientos. Los ingenieros de soporte técnico de Microsoft pueden ayudar a explicar la funcionalidad de un procedimiento en particular, pero no modificarán estos ejemplos para proporcionar funcionalidad adicional ni crearán procedimientos que satisfagan sus requisitos específicos.
NOTA: El siguiente código puede no funcionar correctamente si ha instalado la actualización de seguridad de correo electrónico de Outlook. Para obtener información adicional sobre esta actualización, consulte uno de los siguientes artículos en Microsoft Knowledge Base, según la versión de Outlook que tenga:

262631 OL2000: Información Sobre la Actualización de Seguridad de correo electrónico de Outlook

262617 OL98: Información sobre la actualización de seguridad de correo electrónico de Outlook
Puede usar el método SendObject para enviar un mensaje de correo MAPI mediante programación en Microsoft Access. Sin embargo, el método SendObject no le da acceso a la funcionalidad completa de correo, como la capacidad de adjuntar un archivo externo o establecer la importancia del mensaje. El siguiente ejemplo utiliza la automatización para crear y enviar un mensaje de correo que puede usar para aprovechar muchas funciones de Microsoft Outlook que no están disponibles con el método SendObject.
Hay seis pasos principales para enviar un mensaje de correo de Microsoft Outlook mediante la automatización, de la siguiente manera:

1. Inicialice la sesión de Outlook.

2. Crea un mensaje nuevo.

3. Agregue los destinatarios (A, CC y CCO) y resuelva sus nombres.

4. Establezca propiedades válidas, como el Sujeto, el Cuerpo y la Importancia.

5. Agregue archivos adjuntos (si los hay).

6. Mostrar / Enviar el mensaje.

Envío de un Mensaje de Correo de Microsoft Outlook mediante Programación

1. Cree un archivo de texto de ejemplo llamado Clientes.txt en el C:\My Carpeta de documentos.

2. Inicie Microsoft Access y abra la base de datos de muestra Northwind.mdb.

3. Cree un módulo y escriba la siguiente línea en la sección Declaraciones si aún no está allí:

   Option Explicit
   

4. En el menú Herramientas, haga clic en Referencias.

5. En el cuadro Referencias, haga clic para seleccionar la biblioteca de objetos de Microsoft Outlook 9.0 y, a continuación, haga clic en Aceptar.
   NOTA: Si la biblioteca de objetos de Microsoft Outlook 9.0 no aparece en el cuadro Referencias disponibles, busque en el disco duro el archivo, Msoutl9.olb. Si no puede localizar este archivo, debe ejecutar el programa de configuración de Microsoft Outlook para instalarlo antes de continuar con este ejemplo.

6. Escriba el siguiente procedimiento en el nuevo módulo:

   Sub SendMessage(Optional AttachmentPath)
   Dim objOutlook As Outlook.Application
   Dim objOutlookMsg As Outlook.MailItem
   Dim objOutlookRecip As Outlook.Recipient
   Dim objOutlookAttach As Outlook.Attachment
   ' Create the Outlook session.
   Set objOutlook = CreateObject("Outlook.Application")
   ' Create the message.
   Set objOutlookMsg = objOutlook.CreateItem(olMailItem)
   With objOutlookMsg
   ' Add the To recipient(s) to the message.
   Set objOutlookRecip = .Recipients.Add("Nancy Davolio")
   objOutlookRecip.Type = olTo
   ' Add the CC recipient(s) to the message.
   Set objOutlookRecip = .Recipients.Add("Andrew Fuller")
   objOutlookRecip.Type = olCC
   ' Set the Subject, Body, and Importance of the message.
   .Subject = "This is an Automation test with Microsoft Outlook"
   .Body = "Last test - I promise." & vbCrLf & vbCrLf
   .Importance = olImportanceHigh 'High importance
   ' Add attachments to the message.
   If Not IsMissing(AttachmentPath) Then
   Set objOutlookAttach = .Attachments.Add(AttachmentPath)
   End If
   ' Resolve each Recipient's name.
   For Each objOutlookRecip In .Recipients
   objOutlookRecip.Resolve
   If Not objOutlookRecip.Resolve Then
   objOutlookMsg.Display
   End If
   Next
   .Send
   End With
   Set objOutlookMsg = Nothing
   Set objOutlook = Nothing
   End Sub
   

7. Para probar este procedimiento, escriba la siguiente línea en la ventana Inmediata y, a continuación, presione ENTRAR:

   SendMessage "C:\My Documents\Customers.txt"
   

   Para enviar el mensaje sin especificar un archivo adjunto, omita el argumento al llamar al procedimiento, de la siguiente manera:

   SendMessage