• Articles
• admin

Résumé

Cet article vous montre comment utiliser l’automatisation pour créer et envoyer un message Microsoft Outlook dans Microsoft Access 2000.
Microsoft fournit des exemples de programmation à titre d’illustration uniquement, sans garantie expresse ou implicite. Cela inclut, sans s’y limiter, les garanties implicites de qualité marchande ou d’adéquation à un usage particulier. Cet article suppose que vous connaissez le langage de programmation en cours de démonstration et les outils utilisés pour créer et déboguer des procédures. Les ingénieurs de support Microsoft peuvent vous aider à expliquer les fonctionnalités d’une procédure particulière, mais ils ne modifieront pas ces exemples pour fournir des fonctionnalités supplémentaires ou construire des procédures pour répondre à vos besoins spécifiques.
REMARQUE : Le code suivant peut ne pas fonctionner correctement si vous avez installé la mise à jour de sécurité de messagerie Outlook. Pour plus d’informations sur cette mise à jour, veuillez consulter l’un des articles suivants de la Base de connaissances Microsoft, en fonction de la version d’Outlook dont vous disposez:

262631 OL2000 : Informations Sur la Mise À Jour De Sécurité des E-mails Outlook

262617 OL98: Informations Sur la mise à jour de sécurité des e-mails Outlook
Vous pouvez utiliser la méthode SendObject pour envoyer un message MAPI par programme dans Microsoft Access. Cependant, la méthode SendObject ne vous donne pas accès à des fonctionnalités de messagerie complètes, telles que la possibilité de joindre un fichier externe ou de définir l’importance du message. L’exemple suivant utilise l’automatisation pour créer et envoyer un message électronique que vous pouvez utiliser pour tirer parti de nombreuses fonctionnalités de Microsoft Outlook qui ne sont pas disponibles avec la méthode SendObject.
Il y a six étapes principales pour envoyer un message électronique Microsoft Outlook à l’aide de l’automatisation, comme suit:

1. Initialisez la session Outlook.

2. Créez un nouveau message.

3. Ajoutez les destinataires (To, CC et BCC) et résolvez leurs noms.

4. Définissez des propriétés valides, telles que le Sujet, le Corps et l’Importance.

5. Ajoutez des pièces jointes (le cas échéant).

6. Afficher / Envoyer le message.

Envoi d’un message Mail Microsoft Outlook par programme

1. Créez un exemple de fichier texte nommé Customers.txt dans le C:\My Dossier documents.

2. Démarrez Microsoft Access et ouvrez l’exemple de base de données Northwind.BMD.

3. Créez un module et tapez la ligne suivante dans la section Déclarations s’il n’y est pas déjà:

   Option Explicit
   

4. Dans le menu Outils, cliquez sur Références.

5. Dans la zone Références, cliquez pour sélectionner la bibliothèque d’objets Microsoft Outlook 9.0, puis cliquez sur OK.
   REMARQUE : Si la bibliothèque d’objets Microsoft Outlook 9.0 n’apparaît pas dans la zone Références disponibles, recherchez le fichier Msoutl9 sur votre disque dur.olb. Si vous ne trouvez pas ce fichier, vous devez exécuter le programme d’installation de Microsoft Outlook pour l’installer avant de procéder à cet exemple.

6. Tapez la procédure suivante dans le nouveau module:

   Sub SendMessage(Optional AttachmentPath)
   Dim objOutlook As Outlook.Application
   Dim objOutlookMsg As Outlook.MailItem
   Dim objOutlookRecip As Outlook.Recipient
   Dim objOutlookAttach As Outlook.Attachment
   ' Create the Outlook session.
   Set objOutlook = CreateObject("Outlook.Application")
   ' Create the message.
   Set objOutlookMsg = objOutlook.CreateItem(olMailItem)
   With objOutlookMsg
   ' Add the To recipient(s) to the message.
   Set objOutlookRecip = .Recipients.Add("Nancy Davolio")
   objOutlookRecip.Type = olTo
   ' Add the CC recipient(s) to the message.
   Set objOutlookRecip = .Recipients.Add("Andrew Fuller")
   objOutlookRecip.Type = olCC
   ' Set the Subject, Body, and Importance of the message.
   .Subject = "This is an Automation test with Microsoft Outlook"
   .Body = "Last test - I promise." & vbCrLf & vbCrLf
   .Importance = olImportanceHigh 'High importance
   ' Add attachments to the message.
   If Not IsMissing(AttachmentPath) Then
   Set objOutlookAttach = .Attachments.Add(AttachmentPath)
   End If
   ' Resolve each Recipient's name.
   For Each objOutlookRecip In .Recipients
   objOutlookRecip.Resolve
   If Not objOutlookRecip.Resolve Then
   objOutlookMsg.Display
   End If
   Next
   .Send
   End With
   Set objOutlookMsg = Nothing
   Set objOutlook = Nothing
   End Sub
   

7. Pour tester cette procédure, tapez la ligne suivante dans la fenêtre Immédiate, puis appuyez sur ENTRÉE:

   SendMessage "C:\My Documents\Customers.txt"
   

   Pour envoyer le message sans spécifier de pièce jointe, omettez l’argument lors de l’appel de la procédure, comme suit:

   SendMessage