• Articles
• admin

oversigt

denne artikel viser dig, hvordan du bruger automatisering til at oprette og sende en Microsoft Outlook-meddelelse i Microsoft Access 2000.
Microsoft leverer kun programmeringseksempler til illustration uden garanti, hverken udtrykt eller underforstået. Dette omfatter, men er ikke begrænset til, de underforståede garantier for salgbarhed eller egnethed til et bestemt formål. Denne artikel antager, at du er fortrolig med det programmeringssprog, der demonstreres, og med de værktøjer, der bruges til at oprette og debug procedurer. Microsoft support ingeniører kan hjælpe med at forklare funktionaliteten af en bestemt procedure, men de vil ikke ændre disse eksempler til at give ekstra funktionalitet eller konstruere procedurer til at opfylde dine specifikke krav.
bemærk: følgende kode fungerer muligvis ikke korrekt, hvis du har installeret Outlook e-mail-sikkerhedsopdateringen. For yderligere oplysninger om denne opdatering, se en af følgende artikler i Microsofts videnbase, afhængigt af hvilken version af Outlook du har:

262631 OL2000: oplysninger om sikkerhedsopdateringen til Outlook-E-mail

262617 OL98: oplysninger om Outlook-sikkerhedsopdateringen
du kan bruge SendObject-metoden til at sende en MAPI-mail-meddelelse programmatisk i Microsoft Access. SendObject-metoden giver dig dog ikke adgang til komplet mailfunktionalitet, såsom muligheden for at vedhæfte en ekstern fil eller indstille beskedbetydning. Eksemplet, der følger, bruger automatisering til at oprette og sende en mail, som du kan bruge til at drage fordel af mange funktioner i Microsoft Outlook, der ikke er tilgængelige med SendObject-metoden.
der er seks hovedtrin til at sende en Microsoft Outlook-mailmeddelelse ved hjælp af automatisering som følger:

1. Initialiser Outlook-sessionen.

2. Opret en ny besked.

3. Tilføj modtagerne (til, CC og BCC) og løs deres navne.

4. Angiv gyldige egenskaber, såsom emne, krop og betydning.

5. Tilføj vedhæftede filer (hvis nogen).

6. Vis / Send beskeden.

afsendelse af en Microsoft Outlook – Mail-besked programmatisk

1. Opret en prøve tekstfil med navnet kunder.tekst i C:\My Dokumenter mappe.

2. Start Microsoft Access, og åbn eksempeldatabasen nordvind.mdb.

3. Opret et modul, og skriv følgende linje i afsnittet erklæringer, hvis det ikke allerede er der:

   Option Explicit
   

4. klik på referencer i menuen Funktioner.

5. Klik på for at vælge Microsoft Outlook 9.0-Objektbiblioteket i feltet referencer, og klik derefter på OK.
   BEMÆRK: Hvis Microsoft Outlook 9.0-Objektbiblioteket ikke vises i feltet tilgængelige referencer, skal du gennemse harddisken for filen, Msoutl9.olb. Hvis du ikke kan finde denne fil, skal du køre Microsoft Outlook Setup-programmet for at installere den, før du fortsætter med dette eksempel.

6. Skriv følgende procedure i det nye modul:

   Sub SendMessage(Optional AttachmentPath)
   Dim objOutlook As Outlook.Application
   Dim objOutlookMsg As Outlook.MailItem
   Dim objOutlookRecip As Outlook.Recipient
   Dim objOutlookAttach As Outlook.Attachment
   ' Create the Outlook session.
   Set objOutlook = CreateObject("Outlook.Application")
   ' Create the message.
   Set objOutlookMsg = objOutlook.CreateItem(olMailItem)
   With objOutlookMsg
   ' Add the To recipient(s) to the message.
   Set objOutlookRecip = .Recipients.Add("Nancy Davolio")
   objOutlookRecip.Type = olTo
   ' Add the CC recipient(s) to the message.
   Set objOutlookRecip = .Recipients.Add("Andrew Fuller")
   objOutlookRecip.Type = olCC
   ' Set the Subject, Body, and Importance of the message.
   .Subject = "This is an Automation test with Microsoft Outlook"
   .Body = "Last test - I promise." & vbCrLf & vbCrLf
   .Importance = olImportanceHigh 'High importance
   ' Add attachments to the message.
   If Not IsMissing(AttachmentPath) Then
   Set objOutlookAttach = .Attachments.Add(AttachmentPath)
   End If
   ' Resolve each Recipient's name.
   For Each objOutlookRecip In .Recipients
   objOutlookRecip.Resolve
   If Not objOutlookRecip.Resolve Then
   objOutlookMsg.Display
   End If
   Next
   .Send
   End With
   Set objOutlookMsg = Nothing
   Set objOutlook = Nothing
   End Sub
   

7. for at teste denne procedure skal du skrive følgende linje i vinduet med det samme og derefter trykke på ENTER:

   SendMessage "C:\My Documents\Customers.txt"
   

   hvis du vil sende beskeden uden at angive en vedhæftet fil, skal du udelade argumentet, når du kalder proceduren, som følger:

   SendMessage